"File: area"

"AUXILIARY FUNCITONS"

EVAL_(y,a):=ITERATE(y,x,a,1)

"#######################################"

"USER FUNCITONS"

AREA(y,z,a,b,h):=VECTOR([[k,EVAL_(y,k)],[k,EVAL_(z,k)]],k,a,b,h)

ELP_(b,r):=[b+0.45*r*COS(t),r*SIN(t)]

REV(y,a,b,h):=[[t*(b-a)/(2*pi)+(a+b)/2,EVAL_(y,t*(b-a)/(2*pi)+(a+b)/2)],VECTOR~
(ELP_(k,EVAL_(y,k)),k,a,b,h)]

"#########################################"

"INSTRUCTIONS"

"AREA(y,z,a,b,h) prepares DERIVE to color the area"

"between y(x) and z(x) from x=a to x=b. "

"h determines the density of the shading."

"h=0.1 usually produces a nice picutre."

"REV(y,a,b,h) prepares DERIVE to display the surface of revolution"

"generated by revolving y(x) about the x-axis."

"GGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGG"

"GRAPHICS SETTINGS."

"From the Plot window"

"Options State Rectangular Connected Large"

"The plot for the REV function is parametric"

"The Parameter Domain should be set to MIN: -pi  MAX: pi"

"Use <Ctrl Enter> to accept parameter domain."

"GGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGG"

"EXAMPLES"

"approX the following and then Plot (See graphics settings above)"

"to see the area between sin x and cos x from x=-2 to x=2."

AREA(COS(x),SIN(x),-2,2,0.1)

"approX the following and then Plot (See graphics settings above)"

"to see the solid obtained by rotating cos x from -2 to 2 about the x_axis"

REV(COS(x),-2,2,0.2)