"File: lin_comp"

"AUXILIARY FUNCTIONS"

E_(x,i):=ELEMENT(x,i)

D_(x):=DIMENSION(x)

UNIT_(x):=x/ABS(x)

COMP_(x,v,n):=ITERATES(x . z,z,v,n)

NORM_COMP(x,v,n):=ITERATES(UNIT_(x . z),z,v/ABS(v),n)

PIC_VEC(x):=VECTOR([[0,0],E_(x,k)],k,D_(x))

"##########################################"

"USER FUNCTIONS"

PICTURE(x,v,n):=PIC_VEC(COMP_(x,v,n))

NORM_PICTURE(x,v,n):=PIC_VEC(NORM_COMP(x,v,n))

"######################################"

"INSTRUCTIONS"

"If x is a 2 by 2 matrix, and v is a vector in the plane"

"PICTURE(x,v,n) calculates n iterations of x applied to v."

"NORM_PICTURE replaces the vectors produced by PICTURE by unit vectors."

"GGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGG"

"GRAPHICS SETTINGS"

"From the Plot screen"

"Options State Rectangular Connected Large."

"GGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGG"

"Example 1"

a:=[[1,0.3],[0,1]]

"Simplify the following and then Plot (see graphics settings above)"

"... to see a shearing effect"

PICTURE(a,[1,1],20)

"Example 2"

b:=[[0.3,0.2],[-1,0.5]]

"Simplify the following and then Plot to see a rotation effect"

NORM_PICTURE(b,[1,1],40)